source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/AtaID.asm @ 592

Last change on this file since 592 was 592, checked in by krille_n_, 6 years ago

Changes:

  • The problem with NASM in the previous revision (r591) has been fixed.
  • The colors used by the boot menu and hotkey bar can now be customized by selecting one of a number of pre-defined color themes. Suggestions for additional themes are more than welcome!
  • Large builds are now 10 KB. Small builds are still 8 KB with the exception of the Tiny build which is now 4 KB. In other words, builds are now as small as possible to make it easier to combine them with other BIOSes.
  • Added code to the library to improve drive error handling. XTIDECFG can now handle "Drive Not Ready" errors.
  • Fixed a couple of potential bugs in AtaID.asm (AtaID_GetMaxPioModeToAXandMinCycleTimeToCX); 1) ATA1.bPioMode was treated as a WORD variable. 2) ATA2.bPIOSupp was assumed to be non-zero which would result in PIO mode 3 being returned if the assumption was wrong.
  • Made the same changes in the equivalent function used by BIOSDRVS (DisplayPioModeInformationUsingAtaInfoFromDSBX in AtaInfo.asm).
  • Fixed a bug from r587 in PDC20x30.asm in PDC20x30_GetMaxPioModeToALandMinPioCycleTimeToBX.
  • Fixed a bug from r523 in XTIDECFG where Auto Configure would only set the IRQ on one IDE interface on AT-builds.
  • XTIDECFG will now restore the default settings for the "Serial port virtual device" when reselecting it in the list of device types. This makes it behave consistently for all device types.
  • The eAAM macro is now used regardless if USE_UNDOC_INTEL is defined or not because it is apparently supported on all processors including the NEC V20/V30 CPUs.
  • Renamed the EXCLUDE_FROM_XTIDE_UNIVERSAL_BIOS define to EXCLUDE_FROM_XUB.
  • Added a define to exclude unused library code from BIOSDRVS (EXCLUDE_FROM_BIOSDRVS). This makes it a lot smaller than in previous revisions.
  • All unnecessary CLD-instructions are now under a new define 'CLD_NEEDED' which is only enabled for the BIOS. It is disabled for XTIDECFG and BIOSDRVS but can be enabled if needed by adding this define to the respective makefile. This change was made because these unnecessary instructions are wasteful and should never be needed. In fact, they only serve to hide bugs (in other peoples code) which I strongly believe should be avoided. I recommend people making their own BIOSes from source to not use this define as it's extremely unlikely to be needed.
  • Updated the copyright info in SerDrive and changed an URL to point to the new site.
  • Updated the copyright info and version number in BIOSDRVS.
  • Updated the copyright info in XTIDECFG.
  • Optimizations in general.
File size: 8.7 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for accessing ATA information read with
3;                   IDENTIFY DEVICE command.
4
5;
6; XTIDE Universal BIOS and Associated Tools
7; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
8;
9; This program is free software; you can redistribute it and/or modify
10; it under the terms of the GNU General Public License as published by
11; the Free Software Foundation; either version 2 of the License, or
12; (at your option) any later version.
13;
14; This program is distributed in the hope that it will be useful,
15; but WITHOUT ANY WARRANTY; without even the implied warranty of
16; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17; GNU General Public License for more details.
18; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
19;
20
21; Section containing code
22SECTION .text
23
24;--------------------------------------------------------------------
25; AtaID_VerifyFromESSI
26;   Parameters:
27;       ES:SI:  Ptr to 512-byte ATA information read from the drive
28;   Returns:
29;       ZF:     Set if ATA-ID verified successfully
30;               Cleared if failed to verify ATA-ID
31;   Corrupts registers:
32;       AX, BX, CX
33;--------------------------------------------------------------------
34%ifndef NO_ATAID_VALIDATION
35AtaID_VerifyFromESSI:
36    ; We cannot start by reading ATA version since the ID might be
37    ; corrupted. We start by making sure P-CHS values are valid.
38    ; If they are, we assume the ATA ID to be valid. Fortunately we can do
39    ; further checking for ATA-5 and later since they contain signature and
40    ; checksum bytes. Those are not available for ATA-4 and older.
41
42    ; Verify P-CHS cylinders
43    mov     bx, ATA1.wCylCnt
44    mov     ax, MAX_VALID_PCHS_CYLINDERS
45    call    .CompareCHorSfromOffsetBXtoMaxValueInAX
46
47    mov     bl, ATA1.wHeadCnt & 0FFh
48    mov     ax, MAX_VALID_PCHS_HEADS
49    call    .CompareCHorSfromOffsetBXtoMaxValueInAX
50
51    mov     bl, ATA1.wSPT & 0FFh
52    mov     al, MAX_VALID_PCHS_SECTORS_PER_TRACK
53    call    .CompareCHorSfromOffsetBXtoMaxValueInAX
54
55    ; Check signature byte. It is only found on ATA-5 and later. It should be zero on
56    ; ATA-4 and older.
57    mov     al, [es:si+ATA6.bSignature]
58    test    al, al
59    jz      SHORT .AtaIDverifiedSuccessfully    ; Old ATA so Signature and Checksum is not available
60    cmp     al, A6_wIntegrity_SIGNATURE
61    jne     SHORT .FailedToVerifyAtaID
62
63    ; Check checksum byte since signature was present
64    mov     cx, ATA6_size
65    jmp     Memory_SumCXbytesFromESSItoAL       ; Returns with ZF set according to result
66
67;--------------------------------------------------------------------
68; .CompareCHorSfromOffsetBXtoMaxValueInAX
69;   Parameters:
70;       AX:     Maximum valid C, H or S value
71;       BX:     C, H or S offset to ATA-ID
72;       ES:SI:  Ptr to 512-byte ATA information read from the drive
73;   Returns:
74;       Exits from AtaID_VerifyFromESSI with ZF cleared if invalid value
75;   Corrupts registers:
76;       CX
77;--------------------------------------------------------------------
78.CompareCHorSfromOffsetBXtoMaxValueInAX:
79    mov     cx, [es:bx+si]
80    jcxz    .InvalidPCHorSinOffsetBX
81    cmp     cx, ax          ; Compare to max valid value
82    jbe     SHORT .ValidPCHorSinOffsetBX
83.InvalidPCHorSinOffsetBX:
84    pop     cx              ; Clear return address for this function
85    inc     cx              ; Clear ZF to indicate invalid ATA-ID (safe to do since return address in CX will never be FFFFh)
86.AtaIDverifiedSuccessfully:
87.FailedToVerifyAtaID:
88.ValidPCHorSinOffsetBX:
89    ret
90%endif ; NO_ATAID_VALIDATION
91
92
93;--------------------------------------------------------------------
94; Writes user defined limits from ROMVARS to ATA ID read from the drive.
95; Modifying the ATA ID reduces code and possibilities for bugs since
96; only little further checks are needed elsewhere.
97;
98; AtaID_ModifyESSIforUserDefinedLimitsAndReturnTranslateModeInDX
99;   Parameters:
100;       DS:DI:  Ptr to incomplete Disk Parameter Table
101;       ES:SI:  Ptr to 512-byte ATA information read from the drive
102;       CS:BP:  Ptr to IDEVARS for the controller
103;   Returns:
104;       DX:     User defined P-CHS to L-CHS translate mode
105;   Corrupts registers:
106;       AX, BX
107;--------------------------------------------------------------------
108AtaID_ModifyESSIforUserDefinedLimitsAndReturnTranslateModeInDX:
109    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
110    push    ds
111
112    push    cs
113    pop     ds
114
115    ; Load User Defined CHS or LBA to BX:AX
116    mov     dl, [bx+DRVPARAMS.wFlags]           ; Only load the flags we actually need
117    mov     ax, [bx+DRVPARAMS.wCylinders]       ; Or .dwMaximumLBA
118    mov     bx, [bx+DRVPARAMS.wHeadsAndSectors] ; Or .dwMaximumLBA+2
119
120    push    es
121    pop     ds      ; DS:SI now points to ATA information
122
123    ; * User defined CHS *
124    test    dl, FLG_DRVPARAMS_USERCHS
125    jz      SHORT .NoUserDefinedCHS
126
127    ; Apply new CHS and disable LBA (we also want to set CHS addressing)
128    mov     [si+ATA1.wCylCnt], ax
129    eMOVZX  ax, bl
130    mov     [si+ATA1.wHeadCnt], ax
131    mov     al, bh
132    mov     [si+ATA1.wSPT], ax
133    and     BYTE [si+ATA1.wCaps+1], ~(A1_wCaps_LBA>>8)
134    and     BYTE [si+ATA6.wSetSup83+1], ~(A6_wSetSup83_LBA48>>8)
135.NoUserDefinedCHS:
136
137    ; * User defined LBA *
138    test    dl, FLG_DRVPARAMS_USERLBA
139    jz      SHORT .NoUserDefinedLBA
140
141    ; Apply new LBA and disable LBA48
142    cmp     bx, [si+ATA1.dwLBACnt+2]
143    ja      SHORT .NoUserDefinedLBA     ; Do not set larger than drive
144    jb      SHORT .StoreNewLBA
145    cmp     ax, [si+ATA1.dwLBACnt]
146    ja      SHORT .NoUserDefinedLBA     ; Allow same size to disable LBA48
147.StoreNewLBA:
148    mov     [si+ATA1.dwLBACnt], ax
149    mov     [si+ATA1.dwLBACnt+2], bx
150    and     BYTE [si+ATA6.wSetSup83+1], ~(A6_wSetSup83_LBA48>>8)
151.NoUserDefinedLBA:
152
153    ; * Load P-CHS to L-CHS translate mode to DX *
154    and     dx, BYTE MASK_DRVPARAMS_TRANSLATEMODE
155    eSHR_IM dx, TRANSLATEMODE_FIELD_POSITION
156
157    pop     ds
158    ret
159
160
161%ifdef MODULE_ADVANCED_ATA
162;--------------------------------------------------------------------
163; AtaID_GetMaxPioModeToAXandMinCycleTimeToCX
164;   Parameters:
165;       ES:SI:  Ptr to 512-byte ATA information read from the drive
166;   Returns:
167;       AL:     Max supported PIO mode
168;       AH:     FLGH_DPT_IORDY if IORDY supported, zero otherwise
169;       CX:     Minimum Cycle Time in nanosecs
170;   Corrupts registers:
171;       BX
172;--------------------------------------------------------------------
173AtaID_GetMaxPioModeToAXandMinCycleTimeToCX:
174    ; Get PIO mode and cycle time for PIO 0...2
175%ifdef USE_386
176    movzx   ax, [es:si+ATA1.bPioMode]   ; AH = 0, AL = PIO mode 0, 1 or 2
177%else
178    mov     al, [es:si+ATA1.bPioMode]
179    cbw
180%endif
181    mov     bx, ax
182    eSHL_IM bx, 1                       ; Shift for WORD lookup
183    mov     cx, [cs:bx+.rgwPio0to2CycleTimeInNanosecs]
184
185    ; Check if IORDY is supported
186    test    BYTE [es:si+ATA2.wCaps+1], A2_wCaps_IORDY >> 8
187    jz      SHORT .ReturnPioTimings     ; No PIO 3 or higher if no IORDY
188    mov     ah, FLGH_DPT_IORDY          ; *FIXME* Actually, CF specification v4.1 says that use of IORDY is invalid for PIO modes 5 and 6.
189
190    ; Check if Advanced PIO modes are supported (3 and above)
191    test    BYTE [es:si+ATA2.wFields], A2_wFields_64to70
192    jz      SHORT .ReturnPioTimings
193
194    ; Get Advanced PIO mode (Hard Disks supports up to 4 but CF cards can support 5 and 6)
195    or      bh, [es:si+ATA2.bPIOSupp]
196    jz      SHORT .ReturnPioTimings
197.CheckNextFlag:
198    inc     ax
199    shr     bh, 1
200    jnz     SHORT .CheckNextFlag
201    MIN_U   al, 6                       ; Make sure not above lookup tables
202    mov     cx, [es:si+ATA2.wPIOMinCyF] ; Advanced modes use IORDY
203.ReturnPioTimings:
204    ret
205
206.rgwPio0to2CycleTimeInNanosecs:
207    dw      PIO_0_MIN_CYCLE_TIME_NS
208    dw      PIO_1_MIN_CYCLE_TIME_NS
209    dw      PIO_2_MIN_CYCLE_TIME_NS
210
211
212;--------------------------------------------------------------------
213; AtaID_GetRecoveryTimeToAXfromPioModeInBXandCycleTimeInCX
214;   Parameters:
215;       BX:     PIO Mode
216;       CX:     PIO Cycle Time in nanosecs
217;   Returns:
218;       AX:     Active Time in nanosecs
219;   Corrupts registers:
220;       BX, CX
221;--------------------------------------------------------------------
222AtaID_GetRecoveryTimeToAXfromPioModeInBXandCycleTimeInCX:
223    call    AtaID_GetActiveTimeToAXfromPioModeInBX
224    mov     bl, [cs:bx+.rgbPioModeToAddressValidTimeNs]
225    sub     cx, bx  ; Cycle Time (t0) - Address Valid Time (t1)
226    sub     cx, ax  ; - Active Time (t2)
227    xchg    ax, cx  ; AX = Recovery Time (t2i)
228    ret
229
230.rgbPioModeToAddressValidTimeNs:
231    db      PIO_0_MIN_ADDRESS_VALID_NS
232    db      PIO_1_MIN_ADDRESS_VALID_NS
233    db      PIO_2_MIN_ADDRESS_VALID_NS
234    db      PIO_3_MIN_ADDRESS_VALID_NS
235    db      PIO_4_MIN_ADDRESS_VALID_NS
236    db      PIO_5_MIN_ADDRESS_VALID_NS
237    db      PIO_6_MIN_ADDRESS_VALID_NS
238
239
240;--------------------------------------------------------------------
241; AtaID_GetActiveTimeToAXfromPioModeInBX
242;   Parameters:
243;       BX:     PIO Mode
244;   Returns:
245;       AX:     Active Time in nanosecs
246;   Corrupts registers:
247;       Nothing
248;--------------------------------------------------------------------
249AtaID_GetActiveTimeToAXfromPioModeInBX:
250    eMOVZX  ax, [cs:bx+.rgbPioModeToActiveTimeNs]
251    ret
252
253.rgbPioModeToActiveTimeNs:
254    db      PIO_0_MIN_ACTIVE_TIME_NS
255    db      PIO_1_MIN_ACTIVE_TIME_NS
256    db      PIO_2_MIN_ACTIVE_TIME_NS
257    db      PIO_3_MIN_ACTIVE_TIME_NS
258    db      PIO_4_MIN_ACTIVE_TIME_NS
259    db      PIO_5_MIN_ACTIVE_TIME_NS
260    db      PIO_6_MIN_ACTIVE_TIME_NS
261
262%endif ; MODULE_ADVANCED_ATA
Note: See TracBrowser for help on using the repository browser.