source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/Tools/Address.asm @ 542

Last change on this file since 542 was 542, checked in by aitotat@…, 11 years ago

Changes to XTIDE Universal BIOS:

  • Fixed a bug that allowed EBIOS functions for user defined CHS.
  • Simplified user defined CHS and LBA setup a little.
File size: 6.6 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for address translations.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;---------------------------------------------------------------------
24; Address_ExtractLCHSparametersFromOldInt13hAddress
25;   Parameters:
26;       CH:     Cylinder number, bits 7...0
27;       CL:     Bits 7...6: Cylinder number bits 9 and 8
28;               Bits 5...0: Sector number
29;       DH:     Head number
30;   Returns:
31;       BL:     Sector number (1...63)
32;       BH:     Head number (0...255)
33;       CX:     Cylinder number (0...1023)
34;   Corrupts registers:
35;       Nothing
36;--------------------------------------------------------------------
37ALIGN JUMP_ALIGN
38Address_ExtractLCHSparametersFromOldInt13hAddress:
39    mov     bl, cl              ; Copy sector number...
40    and     bl, 3Fh             ; ...and limit to 1...63
41    sub     cl, bl              ; Remove from cylinder number high
42    eROL_IM cl, 2               ; High bits to beginning
43    mov     bh, dh              ; Copy Head number
44    xchg    cl, ch              ; Cylinder number now in CX
45    ret
46
47
48;---------------------------------------------------------------------
49; Converts LARGE addressing mode LCHS parameters to IDE P-CHS parameters.
50; PCylinder = (LCylinder << n) + (LHead / PHeadCount)
51; PHead     = LHead % PHeadCount
52; PSector   = LSector
53;
54; ConvertLargeModeLCHStoPCHS:
55;   Parameters:
56;       BL:     Sector number (1...63)
57;       BH:     Head number (0...239)
58;       CX:     Cylinder number (0...1023)
59;       DS:DI:  Ptr to Disk Parameter Table
60;   Returns:
61;       BL:     Sector number (1...63)
62;       BH:     Head number (0...15)
63;       CX:     Cylinder number (0...16382)
64;   Corrupts registers:
65;       AX, DX
66;--------------------------------------------------------------------
67ALIGN JUMP_ALIGN
68ConvertLargeModeLCHStoPCHS:
69    ; LHead / PHeadCount and LHead % PHeadCount
70    eMOVZX  ax, bh                  ; Copy L-CHS Head number to AX
71    div     BYTE [di+DPT.bPchsHeads]; AL = LHead / PHeadCount, AH = LHead % PHeadCount
72    mov     bh, ah                  ; Copy P-CHS Head number to BH
73    xor     ah, ah                  ; AX = LHead / PHeadCount
74
75    ; (LCylinder << n) + (LHead / PHeadCount)
76    mov     dx, cx                  ; Copy L-CHS Cylinder number to DX
77    mov     cl, [di+DPT.bFlagsLow]  ; Load shift count
78    and     cl, MASKL_DPT_CHS_SHIFT_COUNT
79    shl     dx, cl                  ; DX = LCylinder << n
80    add     ax, dx                  ; AX = P-CHS Cylinder number
81    xchg    cx, ax                  ; Move P-CHS Cylinder number to CX
82DoNotConvertLCHS:
83    ret
84
85
86;--------------------------------------------------------------------
87; Address_OldInt13hAddressToIdeAddress
88;   Parameters:
89;       CH:     Cylinder number, bits 7...0
90;       CL:     Bits 7...6: Cylinder number bits 9 and 8
91;               Bits 5...0: Starting sector number (1...63)
92;       DH:     Starting head number (0...255)
93;       DS:DI:  Ptr to DPT
94;   Returns:
95;       BL:     LBA Low Register / Sector Number Register (LBA 7...0)
96;       CL:     LBA Mid Register / Low Cylinder Register (LBA 15...8)
97;       CH:     LBA High Register / High Cylinder Register (LBA 23...16)
98;       BH:     Drive and Head Register (LBA 27...24)
99;   Corrupts registers:
100;       AX, DX
101;--------------------------------------------------------------------
102ALIGN JUMP_ALIGN
103Address_OldInt13hAddressToIdeAddress:
104        call    Address_ExtractLCHSparametersFromOldInt13hAddress
105        ACCESSDPT__GET_UNSHIFTED_TRANSLATE_MODE_TO_AXZF
106
107;;; 0: ADDRESSING_MODE_NORMAL
108        jz      SHORT DoNotConvertLCHS
109
110;;; 1: ADDRESSING_MODE_LARGE
111        test    al, FLGL_DPT_ASSISTED_LBA
112        jz      SHORT ConvertLargeModeLCHStoPCHS
113
114;;; 2: ADDRESSING_MODE_ASSISTED_LBA
115        ; Fall through to ConvertAssistedLBAModeLCHStoLBARegisterValues
116
117
118;---------------------------------------------------------------------
119; Converts LCHS parameters to 28-bit LBA address.
120; Only 24-bits are used since LHCS to LBA28 conversion has 8.4GB limit.
121; LBA = ((cylToSeek*headsPerCyl+headToSeek)*sectPerTrack)+sectToSeek-1
122; headsPerCyl and sectPerTrack are the current translation values (L-CHS).
123;
124; Returned address is in same registers that
125; DoNotConvertLCHS and ConvertLargeModeLCHStoPCHS returns.
126;
127; ConvertAssistedLBAModeLCHStoLBARegisterValues:
128;   Parameters:
129;       BL:     Sector number (1...63)
130;       BH:     Head number (0...254)
131;       CX:     Cylinder number (0...1023)
132;       DS:DI:  Ptr to Disk Parameter Table
133;   Returns:
134;       BL:     LBA Low Register / Sector Number Register (LBA 7...0)
135;       CL:     LBA Mid Register / Low Cylinder Register (LBA 15...8)
136;       CH:     LBA High Register / High Cylinder Register (LBA 23...16)
137;       BH:     Drive and Head Register (LBA 27...24)
138;   Corrupts registers:
139;       AX, DX
140;--------------------------------------------------------------------
141ConvertAssistedLBAModeLCHStoLBARegisterValues:
142    ; cylToSeek*headsPerCyl (18-bit result)
143    ; Max = 1023 * 255 = 260,865 = 3FB01h
144    mov     ax, LBA_ASSIST_SPT      ; Load Sectors per Track
145    xchg    cx, ax                  ; Cylinder number to AX, Sectors per Track to CX
146%ifdef USE_386
147    movzx   dx, [di+DPT.bLchsHeads]
148%else
149    cwd
150    mov     dl, [di+DPT.bLchsHeads]
151%endif
152    mul     dx                      ; DX:AX = cylToSeek*headsPerCyl
153
154    ; +=headToSeek (18-bit result)
155    ; Max = 260,865 + 254 = 261,119 = 3FBFFh
156    add     al, bh                  ; Add Head number to DX:AX
157    adc     ah, dh                  ; DH = Zero after previous multiplication
158    adc     dl, dh
159
160    ; *=sectPerTrack (18-bit by 6-bit multiplication with 24-bit result)
161    ; Max = 261,119 * 63 = 16,450,497 = FB03C1h
162    xchg    ax, dx                  ; Hiword to AX, loword to DX
163    mul     cl                      ; AX = hiword * Sectors per Track
164    mov     bh, al                  ; Backup hiword * Sectors per Track
165    xchg    ax, dx                  ; Loword back to AX
166    mul     cx                      ; DX:AX = loword * Sectors per Track
167    add     dl, bh                  ; DX:AX = (cylToSeek*headsPerCyl+headToSeek)*sectPerTrack
168
169    ; +=sectToSeek-1 (24-bit result)
170    ; Max = 16,450,497 + 63 - 1 = 16,450,559 = FB03FFh
171    xor     bh, bh                  ; Sector number now in BX
172    dec     bx                      ; sectToSeek-=1
173    add     ax, bx                  ; Add to loword
174    adc     dl, bh                  ; Add possible carry to byte2, BH=zero
175
176    ; Copy DX:AX to proper return registers
177    xchg    bx, ax                  ; BL = Sector Number Register (LBA 7...0)
178    mov     cl, bh                  ; Low Cylinder Register (LBA 15...8)
179    mov     ch, dl                  ; High Cylinder Register (LBA 23...16)
180    mov     bh, dh                  ; Drive and Head Register (LBA 27...24)
181    ret
Note: See TracBrowser for help on using the repository browser.