source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH9h_HInit.asm @ 550

Last change on this file since 550 was 550, checked in by aitotat@…, 11 years ago

Changes to XTIDE Universal BIOS:

  • CREATE_COMPATIBLE_DPT is now MODULE_COMPATIBLE_TABLES.
  • DPTs pointed by INT 41h and INT 46h are now swapped when swapping drives 81h and 80h.
  • Block mode commands are no longer used when block size is set to 1 with AH=24h.
File size: 9.0 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=9h, Initialize Drive Parameters.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; STORE_ERROR_FLAG_TO_DPT
25;   Parameters:
26;       %1:     Error flag to set
27;       AH:     BIOS Error Code
28;       DS:DI:  Ptr to DPT
29;       CF:     Set if error code in AH
30;   Returns:
31;       CF:     Clear if no error
32;               Set if error flag was set
33;   Corrupts registers:
34;       Nothing
35;--------------------------------------------------------------------
36%macro STORE_ERROR_FLAG_TO_DPT 1
37    mov     al, %1
38    call    SetErrorFlagFromALwithErrorCodeInAH
39%endmacro
40
41
42;--------------------------------------------------------------------
43; Int 13h function AH=9h, Initialize Drive Parameters.
44;
45; AH9h_HandlerForInitializeDriveParameters
46;   Parameters:
47;       DL:     Translated Drive number
48;       DS:DI:  Ptr to DPT (in RAMVARS segment)
49;       SS:BP:  Ptr to IDEPACK
50;   Returns with INTPACK:
51;       AH:     Int 13h return status
52;       CF:     0 if successful, 1 if error
53;--------------------------------------------------------------------
54AH9h_HandlerForInitializeDriveParameters:
55%ifndef USE_186
56    call    AH9h_InitializeDriveForUse
57    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
58%else
59    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
60    ; Fall to AH9h_InitializeDriveForUse
61%endif
62
63
64;--------------------------------------------------------------------
65; Initialize drive to be ready for use.
66;
67; AH9h_InitializeDriveForUse
68;   Parameters:
69;       DS:DI:  Ptr to DPT (in RAMVARS segment)
70;       SS:BP:  Ptr to IDEPACK
71;   Returns:
72;       AH:     Int 13h return status
73;       CF:     0 if successful, 1 if error
74;   Corrupts registers:
75;       AL, CX
76;--------------------------------------------------------------------
77AH9h_InitializeDriveForUse:
78    xor     ax, ax              ; Clear AH to assume no errors
79
80%ifdef MODULE_ADVANCED_ATA
81    ; Clear Initialization Error flags from DPT
82    mov     [di+DPT.bInitError], al
83%endif
84
85%ifdef MODULE_SERIAL
86    ; No need to do this for serial devices
87    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE    ; Clears CF
88    jz      SHORT .ContinueInitialization
89    ret     ; With AH and CF cleared
90.ContinueInitialization:
91%endif
92
93    push    es
94    push    si
95    push    dx
96    push    bx
97
98
99;;; SelectDrive
100    ; Try to select drive and wait until ready
101    call    AccessDPT_GetDriveSelectByteToAL
102    mov     [bp+IDEPACK.bDrvAndHead], al
103    call    Device_SelectDrive
104    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SELECT_DRIVE
105%ifdef USE_386
106    jc      .ReturnWithErrorCodeInAH
107%else
108    jnc     SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
109    jmp     .ReturnWithErrorCodeInAH
110.ContinueInitializationSinceDriveSelectedSuccesfully:
111%endif
112
113
114;;; Set XT-CF mode
115%ifdef MODULE_8BIT_IDE_ADVANCED
116    call    AH1Eh_GetCurrentXTCFmodeToAX
117    call    AH9h_SetModeFromALtoXTCF
118    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
119.DoNotSetXTCFmode:
120%endif  ; MODULE_8BIT_IDE_ADVANCED
121
122%ifdef MODULE_8BIT_IDE
123;;; Set 8-bit PIO mode
124    call    AH9h_Enable8bitModeForDevice8bitAta
125    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_8BIT_MODE
126.DoNotSet8bitMode:
127%endif ; MODULE_8BIT_IDE
128
129
130;;; InitializeDeviceParameters
131    ; Initialize Logical Sectors per Track and Max Head number
132    mov     ax, [di+DPT.wPchsHeadsAndSectors]
133    dec     ax                          ; Max Head number
134    xchg    ah, al
135    mov     dl, al                      ; Sectors per track
136    mov     al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
137    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
138    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
139    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
140.SkipInitializeDeviceParameters:
141
142
143;;; SetWriteCache
144    ; Enable or Disable Write Cache
145    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
146    mov     bl, [cs:bx+DRVPARAMS.wFlags]
147    push    bx  ; Save .wFlags for later use in InitializeBlockMode
148    and     bx, BYTE MASK_DRVPARAMS_WRITECACHE
149    jz      SHORT .SkipSetWriteCache        ; DEFAULT_WRITE_CACHE
150    mov     si, [cs:bx+.rgbWriteCacheCommands]
151    call    AH23h_SetControllerFeatures
152    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
153.SkipSetWriteCache:
154
155
156;;; RecalibrateDrive
157    ; Recalibrate drive by seeking to cylinder 0
158    call    AH11h_RecalibrateDrive
159    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
160
161
162;;; InitializeBlockMode
163    ; Initialize block mode transfers
164    pop     ax  ; Restore .wFlags saved in SetWriteCache
165    test    al, FLG_DRVPARAMS_BLOCKMODE ; Tested here so block mode can be enabled with AH=24h
166    jz      SHORT .BlockModeDisabled
167
168    ; Try block sizes until we find largest possible supported by drive
169    mov     bl, 128
170.TryNextBlockSize:
171    mov     al, bl
172    call    AH24h_SetBlockSize  ; Stores block size to DPT
173    jnc     SHORT .SupportedBlockSizeFound
174    shr     bl, 1
175    jnc     SHORT .TryNextBlockSize
176    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
177.BlockModeDisabled:
178.SupportedBlockSizeFound:
179
180
181%ifdef MODULE_ADVANCED_ATA
182;;; InitializePioMode
183    ; Initialize fastest supported PIO mode
184    mov     dl, PIO_DEFAULT_MODE_DISABLE_IORDY
185    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
186    jz      SHORT .IordyNotSupported
187
188    ; Advanced PIO mode 3 and above
189    mov     dl, [di+DPT_ADVANCED_ATA.bPioMode]
190    or      dl, PIO_FLOW_CONTROL_MODE_xxx
191
192.IordyNotSupported:
193    mov     si, FEATURE_SET_TRANSFER_MODE
194    call    AH23h_SetControllerFeatures
195    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_PIO_MODE
196%endif ; MODULE_ADVANCED_ATA
197
198
199%ifdef MODULE_FEATURE_SETS
200;;; InitStandbyTimer
201    ; Initialize the standby timer (if supported)
202    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
203    jz      SHORT .NoPowerManagementSupport
204
205    mov     al, COMMAND_IDLE
206    mov     dl, [cs:ROMVARS.bIdleTimeout]
207    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
208    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
209    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
210.NoPowerManagementSupport:
211%endif ; MODULE_FEATURE_SETS
212
213
214    ; There might have been several errors so just return one error code for them all
215.ReturnWithErrorCodeInAH:
216%ifdef MODULE_ADVANCED_ATA
217    mov     ah, [di+DPT.bInitError]
218    test    ah, ah  ; Clears CF
219    jz      SHORT .ReturnWithSuccess
220    mov     ah, RET_HD_RESETFAIL
221    stc
222.ReturnWithSuccess:
223%endif
224
225    pop     bx
226    pop     dx
227    pop     si
228    pop     es
229    ret
230
231
232.rgbWriteCacheCommands:
233    db      0                               ; DEFAULT_WRITE_CACHE
234    db      FEATURE_DISABLE_WRITE_CACHE     ; DISABLE_WRITE_CACHE
235    db      FEATURE_ENABLE_WRITE_CACHE      ; ENABLE_WRITE_CACHE
236
237
238
239;--------------------------------------------------------------------
240; SetErrorFlagFromALwithErrorCodeInAH
241;   Parameters:
242;       AH:     BIOS Error Code
243;       AL:     Error flag to set
244;       DS:DI:  Ptr to DPT
245;       CF:     Set if error code in AH
246;               Clear if AH = 0
247;   Returns:
248;       CF:     Clear if no error
249;               Set if error flag was set
250;   Corrupts registers:
251;       Nothing
252;--------------------------------------------------------------------
253IgnoreInvalidCommandError:
254    xor     ah, ah  ; Clears CF
255SetErrorFlagFromALwithErrorCodeInAH:
256    jnc     SHORT .NoErrorFlagToSet
257    cmp     ah, RET_HD_INVALID
258    jbe     SHORT IgnoreInvalidCommandError
259
260    or      [di+DPT.bInitError], al
261    stc
262.NoErrorFlagToSet:
263    ret
264
265
266%ifdef MODULE_8BIT_IDE_ADVANCED
267;--------------------------------------------------------------------
268; AH9h_SetModeFromALtoXTCF
269;   Parameters:
270;       AL:     XT-CF Mode to set
271;       DS:DI:  Ptr to DPT (in RAMVARS segment)
272;       SS:BP:  Ptr to IDEPACK
273;   Returns:
274;       AH:     Int 13h return status
275;       CF:     Clear if successful or device is not XT-CF
276;               Set if failed to set mode for XT-CF
277;   Corrupts registers:
278;       AL, BX, CX, DX, SI
279;--------------------------------------------------------------------
280AH9h_SetModeFromALtoXTCF:
281    call    AccessDPT_IsThisDeviceXTCF
282    jne     SHORT IgnoreInvalidCommandError
283    jmp     AH1Eh_ChangeXTCFmodeBasedOnModeInAL
284%endif ; MODULE_8BIT_IDE_ADVANCED
285
286
287%ifdef MODULE_8BIT_IDE
288;--------------------------------------------------------------------
289; AH9h_Enable8bitModeForDevice8bitAta
290;   Parameters:
291;       DS:DI:  Ptr to DPT (in RAMVARS segment)
292;       SS:BP:  Ptr to IDEPACK
293;   Returns:
294;       AH:     Int 13h return status
295;       CF:     Clear if successful or device is not DEVICE_8BIT_ATA
296;               Set if failed to set 8-bit mode for DEVICE_8BIT_ATA
297;   Corrupts registers:
298;       AL, BX, CX, DX, SI
299;--------------------------------------------------------------------
300AH9h_Enable8bitModeForDevice8bitAta:
301    cmp     BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_ATA
302    jne     SHORT IgnoreInvalidCommandError
303    jmp     AH23h_Enable8bitPioMode
304%endif
Note: See TracBrowser for help on using the repository browser.