source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH9h_HInit.asm @ 542

Last change on this file since 542 was 542, checked in by aitotat@…, 11 years ago

Changes to XTIDE Universal BIOS:

  • Fixed a bug that allowed EBIOS functions for user defined CHS.
  • Simplified user defined CHS and LBA setup a little.
File size: 9.1 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=9h, Initialize Drive Parameters.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; STORE_ERROR_FLAG_TO_DPT
25;   Parameters:
26;       %1:     Error flag to set
27;       AH:     BIOS Error Code
28;       DS:DI:  Ptr to DPT
29;       CF:     Set if error code in AH
30;   Returns:
31;       CF:     Clear if no error
32;               Set if error flag was set
33;   Corrupts registers:
34;       Nothing
35;--------------------------------------------------------------------
36%macro STORE_ERROR_FLAG_TO_DPT 1
37    mov     al, %1
38    call    SetErrorFlagFromALwithErrorCodeInAH
39%endmacro
40
41
42;--------------------------------------------------------------------
43; Int 13h function AH=9h, Initialize Drive Parameters.
44;
45; AH9h_HandlerForInitializeDriveParameters
46;   Parameters:
47;       DL:     Translated Drive number
48;       DS:DI:  Ptr to DPT (in RAMVARS segment)
49;       SS:BP:  Ptr to IDEPACK
50;   Returns with INTPACK:
51;       AH:     Int 13h return status
52;       CF:     0 if successful, 1 if error
53;--------------------------------------------------------------------
54AH9h_HandlerForInitializeDriveParameters:
55%ifndef USE_186
56    call    AH9h_InitializeDriveForUse
57    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
58%else
59    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
60    ; Fall to AH9h_InitializeDriveForUse
61%endif
62
63
64;--------------------------------------------------------------------
65; Initialize drive to be ready for use.
66;
67; AH9h_InitializeDriveForUse
68;   Parameters:
69;       DS:DI:  Ptr to DPT (in RAMVARS segment)
70;       SS:BP:  Ptr to IDEPACK
71;   Returns:
72;       AH:     Int 13h return status
73;       CF:     0 if successful, 1 if error
74;   Corrupts registers:
75;       AL, CX
76;--------------------------------------------------------------------
77AH9h_InitializeDriveForUse:
78    xor     ax, ax              ; Clear AH to assume no errors
79
80%ifdef MODULE_ADVANCED_ATA
81    ; Clear Initialization Error flags from DPT
82    mov     [di+DPT.bInitError], al
83%endif
84
85%ifdef MODULE_SERIAL
86    ; No need to do this for serial devices
87    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE    ; Clears CF
88    jz      SHORT .ContinueInitialization
89    ret     ; With AH and CF cleared
90.ContinueInitialization:
91%endif
92
93    push    es
94    push    si
95    push    dx
96    push    bx
97
98
99;;; SelectDrive
100    ; Try to select drive and wait until ready
101    call    AccessDPT_GetDriveSelectByteToAL
102    mov     [bp+IDEPACK.bDrvAndHead], al
103    call    Device_SelectDrive
104    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SELECT_DRIVE
105%ifdef USE_386
106    jc      .ReturnWithErrorCodeInAH
107%else
108    jnc     SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
109    jmp     .ReturnWithErrorCodeInAH
110.ContinueInitializationSinceDriveSelectedSuccesfully:
111%endif
112
113
114;;; Set XT-CF mode
115%ifdef MODULE_8BIT_IDE_ADVANCED
116    call    AccessDPT_GetIdevarsToCSBX
117    mov     al, [cs:bx+IDEVARS.bXTCFcontrolRegister]
118    call    AH9h_SetModeFromALtoXTCF
119    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
120.DoNotSetXTCFmode:
121%endif  ; MODULE_8BIT_IDE_ADVANCED
122
123%ifdef MODULE_8BIT_IDE
124;;; Set 8-bit PIO mode
125    call    AH9h_Enable8bitModeForDevice8bitAta
126    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_8BIT_MODE
127.DoNotSet8bitMode:
128%endif ; MODULE_8BIT_IDE
129
130
131;;; InitializeDeviceParameters
132    ; Initialize Logical Sectors per Track and Max Head number
133    mov     ax, [di+DPT.wPchsHeadsAndSectors]
134    dec     ax                          ; Max Head number
135    xchg    ah, al
136    mov     dl, al                      ; Sectors per track
137    mov     al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
138    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
139    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
140    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
141.SkipInitializeDeviceParameters:
142
143
144;;; SetWriteCache
145    ; Enable or Disable Write Cache
146    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
147    mov     bl, [cs:bx+DRVPARAMS.wFlags]
148    push    bx  ; Save .wFlags for later use in InitializeBlockMode
149    and     bx, BYTE MASK_DRVPARAMS_WRITECACHE
150    jz      SHORT .SkipSetWriteCache        ; DEFAULT_WRITE_CACHE
151    mov     si, [cs:bx+.rgbWriteCacheCommands]
152    call    AH23h_SetControllerFeatures
153    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
154.SkipSetWriteCache:
155
156
157;;; RecalibrateDrive
158    ; Recalibrate drive by seeking to cylinder 0
159    call    AH11h_RecalibrateDrive
160    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
161
162
163;;; InitializeBlockMode
164    ; Initialize block mode transfers
165    pop     ax  ; Restore .wFlags saved in SetWriteCache
166    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
167    jz      SHORT .BlockModeNotSupportedOrDisabled
168    test    al, FLG_DRVPARAMS_BLOCKMODE
169    jz      SHORT .BlockModeNotSupportedOrDisabled
170
171    ; Try block sizes until we find largest possible supported by drive
172    mov     bl, 128
173.TryNextBlockSize:
174    mov     al, bl
175    call    AH24h_SetBlockSize  ; Stores block size to DPT
176    jnc     SHORT .SupportedBlockSizeFound
177    shr     bl, 1
178    jnc     SHORT .TryNextBlockSize
179    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
180.BlockModeNotSupportedOrDisabled:
181.SupportedBlockSizeFound:
182
183
184%ifdef MODULE_ADVANCED_ATA
185;;; InitializePioMode
186    ; Initialize fastest supported PIO mode
187    mov     dl, PIO_DEFAULT_MODE_DISABLE_IORDY
188    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
189    jz      SHORT .IordyNotSupported
190
191    ; Advanced PIO mode 3 and above
192    mov     dl, [di+DPT_ADVANCED_ATA.bPioMode]
193    or      dl, PIO_FLOW_CONTROL_MODE_xxx
194
195.IordyNotSupported:
196    mov     si, FEATURE_SET_TRANSFER_MODE
197    call    AH23h_SetControllerFeatures
198    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_PIO_MODE
199%endif ; MODULE_ADVANCED_ATA
200
201
202%ifdef MODULE_FEATURE_SETS
203;;; InitStandbyTimer
204    ; Initialize the standby timer (if supported)
205    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
206    jz      SHORT .NoPowerManagementSupport
207
208    mov     al, COMMAND_IDLE
209    mov     dl, [cs:ROMVARS.bIdleTimeout]
210    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
211    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
212    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
213.NoPowerManagementSupport:
214%endif ; MODULE_FEATURE_SETS
215
216
217    ; There might have been several errors so just return one error code for them all
218.ReturnWithErrorCodeInAH:
219%ifdef MODULE_ADVANCED_ATA
220    mov     ah, [di+DPT.bInitError]
221    test    ah, ah  ; Clears CF
222    jz      SHORT .ReturnWithSuccess
223    mov     ah, RET_HD_RESETFAIL
224    stc
225.ReturnWithSuccess:
226%endif
227
228    pop     bx
229    pop     dx
230    pop     si
231    pop     es
232    ret
233
234
235.rgbWriteCacheCommands:
236    db      0                               ; DEFAULT_WRITE_CACHE
237    db      FEATURE_DISABLE_WRITE_CACHE     ; DISABLE_WRITE_CACHE
238    db      FEATURE_ENABLE_WRITE_CACHE      ; ENABLE_WRITE_CACHE
239
240
241
242;--------------------------------------------------------------------
243; SetErrorFlagFromALwithErrorCodeInAH
244;   Parameters:
245;       AH:     BIOS Error Code
246;       AL:     Error flag to set
247;       DS:DI:  Ptr to DPT
248;       CF:     Set if error code in AH
249;               Clear if AH = 0
250;   Returns:
251;       CF:     Clear if no error
252;               Set if error flag was set
253;   Corrupts registers:
254;       Nothing
255;--------------------------------------------------------------------
256IgnoreInvalidCommandError:
257    xor     ah, ah  ; Clears CF
258SetErrorFlagFromALwithErrorCodeInAH:
259    jnc     SHORT .NoErrorFlagToSet
260    cmp     ah, RET_HD_INVALID
261    jbe     SHORT IgnoreInvalidCommandError
262
263    or      [di+DPT.bInitError], al
264    stc
265.NoErrorFlagToSet:
266    ret
267
268
269%ifdef MODULE_8BIT_IDE_ADVANCED
270;--------------------------------------------------------------------
271; AH9h_SetModeFromALtoXTCF
272;   Parameters:
273;       AL:     XT-CF Mode to set
274;       DS:DI:  Ptr to DPT (in RAMVARS segment)
275;       SS:BP:  Ptr to IDEPACK
276;   Returns:
277;       AH:     Int 13h return status
278;       CF:     Clear if successful or device is not XT-CF
279;               Set if failed to set mode for XT-CF
280;   Corrupts registers:
281;       AL, BX, CX, DX, SI
282;--------------------------------------------------------------------
283AH9h_SetModeFromALtoXTCF:
284    call    AccessDPT_IsThisDeviceXTCF
285    jne     SHORT IgnoreInvalidCommandError
286    jmp     AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL
287%endif ; MODULE_8BIT_IDE_ADVANCED
288
289%ifdef MODULE_8BIT_IDE
290;--------------------------------------------------------------------
291; AH9h_Enable8bitModeForDevice8bitAta
292;   Parameters:
293;       DS:DI:  Ptr to DPT (in RAMVARS segment)
294;       SS:BP:  Ptr to IDEPACK
295;   Returns:
296;       AH:     Int 13h return status
297;       CF:     Clear if successful or device is not DEVICE_8BIT_ATA
298;               Set if failed to set 8-bit mode for DEVICE_8BIT_ATA
299;   Corrupts registers:
300;       AL, BX, CX, DX, SI
301;--------------------------------------------------------------------
302AH9h_Enable8bitModeForDevice8bitAta:
303    cmp     BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_ATA
304    jne     SHORT IgnoreInvalidCommandError
305    jmp     AH23h_Enable8bitPioMode
306%endif
Note: See TracBrowser for help on using the repository browser.