source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH24h_HSetBlocks.asm @ 150

Last change on this file since 150 was 150, checked in by aitotat, 13 years ago

Changes to XTIDE Universal BIOS:

  • Redesigned Disk Parameter Tables.
  • Code generalizations for supporting non-IDE devices in the future.
File size: 2.2 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=24h, Set Multiple Blocks.
3
4; Section containing code
5SECTION .text
6
7;--------------------------------------------------------------------
8; Int 13h function AH=24h, Set Multiple Blocks.
9;
10; AH24h_HandlerForSetMultipleBlocks
11;   Parameters:
12;       AL:     Same as in INTPACK
13;       DL:     Translated Drive number
14;       DS:DI:  Ptr to DPT (in RAMVARS segment)
15;       SS:BP:  Ptr to IDEPACK
16;   Parameters on INTPACK:
17;       AL:     Number of Sectors per Block (1, 2, 4, 8, 16, 32, 64 or 128)
18;   Returns with INTPACK:
19;       AH:     Int 13h return status
20;       CF:     0 if succesfull, 1 if error
21;--------------------------------------------------------------------
22ALIGN JUMP_ALIGN
23AH24h_HandlerForSetMultipleBlocks:
24    test    WORD [di+DPT.wFlags], FLG_DPT_BLOCK_MODE_SUPPORTED
25    jnz     SHORT .TryToSetBlockMode
26    stc
27    mov     ah, RET_HD_INVALID
28    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
29
30ALIGN JUMP_ALIGN
31.TryToSetBlockMode:
32%ifndef USE_186
33    call    AH24h_SetBlockSize
34    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
35%else
36    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
37    ; Fall through to AH24h_SetBlockSize
38%endif
39
40
41;--------------------------------------------------------------------
42; AH24h_SetBlockSize
43;   Parameters:
44;       AL:     Number of Sectors per Block (1, 2, 4, 8, 16, 32, 64 or 128)
45;       DS:DI:  Ptr to DPT (in RAMVARS segment)
46;       SS:BP:  Ptr to IDEPACK
47;   Returns:
48;       AH:     Int 13h return status
49;       CF:     0 if succesfull, 1 if error
50;   Corrupts registers:
51;       AL, BX, CX, DX
52;--------------------------------------------------------------------
53ALIGN JUMP_ALIGN
54AH24h_SetBlockSize:
55    MIN_U   al, MAX_SUPPORTED_BLOCK_SIZE_IN_SECTORS
56    push    ax
57    xchg    dx, ax          ; DL = Block size (Sector Count Register)
58    mov     al, COMMAND_SET_MULTIPLE_MODE
59    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRDY, FLG_STATUS_DRDY)
60    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
61    pop     bx
62    jc      SHORT .DisableBlockMode
63
64    ; Store new block size to DPT and return
65    mov     [di+DPT_ATA.bSetBlock], bl              ; Store new block size
66    ret
67.DisableBlockMode:
68    mov     BYTE [di+DPT_ATA.bSetBlock], 1          ; Disable block mode
69    ret
Note: See TracBrowser for help on using the repository browser.