source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Device/IDE/IdeTransfer.asm @ 538

Last change on this file since 538 was 538, checked in by aitotat@…, 11 years ago

Changes to XTIDE Universal BIOS:

  • Segment overflow is now checked when transfer buffer pointer is normalized (AT builds only).
File size: 11.8 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   IDE Device transfer functions.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Structure containing variables for PIO transfer functions.
21; This struct must not be larger than IDEPACK without INTPACK.
22struc PIOVARS   ; Must not be larger than 9 bytes! See IDEPACK in RamVars.inc.
23    .wDataPort              resb    2   ; 0-1, IDE Data Port
24    .fnXfer                 resb    2   ; 2-3, Offset to transfer function
25    .wSectorsInBlock        resb    2   ; 4-5, Block size in sectors
26    .bSectorsLeft           resb    1   ; 6, Sectors left to transfer
27                            resb    1   ; 7, IDEPACK.bDeviceControl
28    .bSectorsDone           resb    1   ; 8, Number of sectors xferred
29endstruc
30
31
32; Section containing code
33SECTION .text
34
35;--------------------------------------------------------------------
36; IdeTransfer_StartWithCommandInAL
37;   Parameters:
38;       AL:     IDE command that was used to start the transfer
39;               (all PIO read and write commands including Identify Device)
40;       ES:SI:  Ptr to data buffer
41;       DS:DI:  Ptr to DPT (in RAMVARS segment)
42;       SS:BP:  Ptr to IDEPACK
43;   Returns:
44;       AH:     INT 13h Error Code
45;       CX:     Number of successfully transferred sectors
46;       CF:     Cleared if success, Set if error
47;   Corrupts registers:
48;       AL, BX, DX, SI, ES
49;--------------------------------------------------------------------
50ALIGN JUMP_ALIGN
51IdeTransfer_StartWithCommandInAL:
52    ; Are we reading or writing?
53    test    al, 16  ; Bit 4 is cleared on all the read commands but set on 3 of the 4 write commands
54    mov     ah, [bp+IDEPACK.bSectorCount]
55    jnz     SHORT WriteToDrive
56    cmp     al, COMMAND_WRITE_MULTIPLE
57    je      SHORT WriteToDrive
58    ; Fall to ReadFromDrive
59
60;--------------------------------------------------------------------
61; ReadFromDrive
62;   Parameters:
63;       AH:     Number of sectors to transfer (1...128)
64;       ES:SI:  Ptr to buffer to receive data
65;       DS:DI:  Ptr to DPT (in RAMVARS segment)
66;       SS:BP:  Ptr to PIOVARS
67;   Returns:
68;       DS:DI:  Ptr to DPT (in RAMVARS segment)
69;       AH:     BIOS Error code
70;       CX:     Number of successfully transferred sectors
71;       CF:     0 if transfer successful
72;               1 if any error
73;   Corrupts registers:
74;       AL, BX, DX, SI, ES
75;--------------------------------------------------------------------
76ReadFromDrive:
77    ; Prepare to read data to ESSI
78    mov     bx, g_rgfnPioRead
79    call    InitializePiovarsInSSBPwithSectorCountInAH
80%ifdef USE_AT
81    jc      SHORT ReturnWithTransferErrorInAH
82%endif
83
84    ; Wait until drive is ready to transfer
85    call    IdeWait_IRQorDRQ                    ; Wait until ready to transfer
86    jc      SHORT ReturnWithTransferErrorInAH
87    xchg    si, di                              ; ES:DI now points buffer
88
89    mov     cx, [bp+PIOVARS.wSectorsInBlock]    ; Max 128
90
91ALIGN JUMP_ALIGN
92.ReadNextBlockFromDrive:
93    mov     dx, [bp+PIOVARS.wDataPort]
94    cmp     [bp+PIOVARS.bSectorsLeft], cl
95    jbe     SHORT .ReadLastBlockFromDrive
96    call    [bp+PIOVARS.fnXfer]
97
98    ; Wait until ready for next block and check for errors
99    xchg    di, si                              ; DS:DI now points DPT
100    call    IdeWait_IRQorDRQ                    ; Wait until ready to transfer
101    jc      SHORT ReturnWithTransferErrorInAH
102    xchg    si, di                              ; ES:DI now points buffer
103
104    ; Increment number of successfully read sectors
105    mov     cx, [bp+PIOVARS.wSectorsInBlock]
106    sub     [bp+PIOVARS.bSectorsLeft], cl
107    add     [bp+PIOVARS.bSectorsDone], cl
108    jmp     SHORT .ReadNextBlockFromDrive
109
110ALIGN JUMP_ALIGN
111.ReadLastBlockFromDrive:
112    mov     cl, [bp+PIOVARS.bSectorsLeft]       ; CH is already zero
113    push    cx
114    call    [bp+PIOVARS.fnXfer]                 ; Transfer possibly partial block
115
116    ; Check for errors in last block
117    mov     di, si                              ; DS:DI now points DPT
118CheckErrorsAfterTransferringLastBlock:
119    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRQ, FLG_STATUS_BSY)
120    call    IdeWait_PollStatusFlagInBLwithTimeoutInBH
121    pop     cx  ; [bp+PIOVARS.bSectorsLeft]
122    jc      SHORT ReturnWithTransferErrorInAH
123
124    ; All sectors successfully transferred
125    add     cx, [bp+PIOVARS.bSectorsDone]       ; Never sets CF
126    ret
127
128    ; Return number of successfully read sectors
129ReturnWithTransferErrorInAH:
130%ifdef USE_386
131    movzx   cx, [bp+PIOVARS.bSectorsDone]
132%else
133    mov     cl, [bp+PIOVARS.bSectorsDone]
134    mov     ch, 0                               ; Preserve CF
135%endif
136    ret
137
138
139;--------------------------------------------------------------------
140; WriteToDrive
141;   Parameters:
142;       AH:     Number of sectors to transfer (1...128)
143;       DS:DI:  Ptr to DPT (in RAMVARS segment)
144;       ES:SI:  Ptr to buffer containing data
145;       SS:BP:  Ptr to PIOVARS
146;   Returns:
147;       AH:     BIOS Error code
148;       CX:     Number of successfully transferred sectors
149;       CF:     0 if transfer successful
150;               1 if any error
151;   Corrupts registers:
152;       AL, BX, DX, SI, ES
153;--------------------------------------------------------------------
154ALIGN JUMP_ALIGN
155WriteToDrive:
156    ; Prepare to write data from ESSI
157    mov     bx, g_rgfnPioWrite
158    call    InitializePiovarsInSSBPwithSectorCountInAH
159%ifdef USE_AT
160    jc      SHORT ReturnWithTransferErrorInAH
161%endif
162
163    ; Always poll when writing first block (IRQs are generated for following blocks)
164    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRQ, FLG_STATUS_DRQ)
165    call    IdeWait_PollStatusFlagInBLwithTimeoutInBH
166    jc      SHORT ReturnWithTransferErrorInAH
167
168    mov     cx, [bp+PIOVARS.wSectorsInBlock]    ; Max 128
169
170ALIGN JUMP_ALIGN
171.WriteNextBlockToDrive:
172    mov     dx, [bp+PIOVARS.wDataPort]
173    cmp     [bp+PIOVARS.bSectorsLeft], cl
174    jbe     SHORT .WriteLastBlockToDrive
175    call    [bp+PIOVARS.fnXfer]
176
177    ; Wait until ready for next block and check for errors
178    call    IdeWait_IRQorDRQ                    ; Wait until ready to transfer
179    jc      SHORT ReturnWithTransferErrorInAH
180
181    ; Increment number of successfully written sectors
182    mov     cx, [bp+PIOVARS.wSectorsInBlock]
183    sub     [bp+PIOVARS.bSectorsLeft], cl
184    add     [bp+PIOVARS.bSectorsDone], cl
185    jmp     SHORT .WriteNextBlockToDrive
186
187ALIGN JUMP_ALIGN
188.WriteLastBlockToDrive:
189    mov     cl, [bp+PIOVARS.bSectorsLeft]       ; CH is already zero
190    push    cx
191%ifdef USE_186
192    push    CheckErrorsAfterTransferringLastBlock
193    jmp     [bp+PIOVARS.fnXfer]                 ; Transfer possibly partial block
194%else
195    call    [bp+PIOVARS.fnXfer]                 ; Transfer possibly partial block
196    jmp     SHORT CheckErrorsAfterTransferringLastBlock
197%endif
198
199
200;--------------------------------------------------------------------
201; InitializePiovarsInSSBPwithSectorCountInAH
202;   Parameters:
203;       AH:     Number of sectors to transfer (1...128)
204;       BX:     Offset to transfer function lookup table
205;       DS:DI:  Ptr to DPT (in RAMVARS segment)
206;       ES:SI:  Ptr to data buffer
207;       SS:BP:  Ptr to PIOVARS
208;   Returns:
209;       ES:SI:  Normalized pointer
210;       AH:     INT 13h Error Code (only when CF set)
211;       CF:     Set of failed to normalize pointer (segment overflow)
212;               Cleared if success
213;   Corrupts registers:
214;       AL, BX, DX
215;--------------------------------------------------------------------
216ALIGN JUMP_ALIGN
217InitializePiovarsInSSBPwithSectorCountInAH:
218    ; Store sizes and Data Port
219    mov     [bp+PIOVARS.bSectorsLeft], ah
220%ifdef USE_AT
221    xchg    dx, ax
222%endif
223    mov     ax, [di+DPT.wBasePort]
224    mov     [bp+PIOVARS.wDataPort], ax
225    eMOVZX  ax, [di+DPT_ATA.bBlockSize]
226    mov     [bp+PIOVARS.wSectorsInBlock], ax
227    mov     [bp+PIOVARS.bSectorsDone], ah       ; Zero
228
229    ; Get transfer function based on bus type
230    xchg    ax, bx                              ; Lookup table offset to AX
231    mov     bl, [di+DPT_ATA.bDevice]
232%ifdef MODULE_8BIT_IDE_ADVANCED
233    mov     dl, bl
234%endif
235    add     bx, ax
236    mov     ax, [cs:bx]                         ; Load offset to transfer function
237    mov     [bp+PIOVARS.fnXfer], ax
238
239    ; Normalize pointer for PIO-transfers and convert to physical address for DMA transfers
240%ifdef MODULE_8BIT_IDE_ADVANCED
241    cmp     dl, DEVICE_8BIT_XTCF_DMA
242    jb      SHORT IdeTransfer_NormalizePointerInESSI
243
244    ; Convert ES:SI to physical address
245%ifdef USE_186          ; Bytes EU Cycles(286)
246    mov     ax, es      ; 2     2
247    rol     ax, 4       ; 3     9
248    mov     dx, ax      ; 2     2
249    and     ax, BYTE 0Fh; 3     3
250    xor     dx, ax      ; 2     2
251    add     si, dx      ; 2     2
252    adc     al, ah      ; 2     2
253    mov     es, ax      ; 2     2
254    ;------------------------------------
255                        ; 18    24
256%else ; 808x
257
258%if 0
259                        ; Bytes EU Cycles(808x)
260    mov     al, 4       ; 2     4
261    mov     dx, es      ; 2     2
262    xchg    cx, ax      ; 1     3
263    rol     dx, cl      ; 2     24
264    mov     cx, dx      ; 2     2
265    xchg    cx, ax      ; 1     3
266    and     ax, BYTE 0Fh; 3     4
267    xor     dx, ax      ; 2     3
268    add     si, dx      ; 2     3
269    adc     al, ah      ; 2     3
270    mov     es, ax      ; 2     2
271    ;------------------------------------
272                        ; 21    53
273;
274; Judging by the Execution Unit cycle count the above block of code is
275; apparently slower. However, the shifts and rotates in the block below
276; execute faster than the Bus Interface Unit on an 8088 can fetch them,
277; thus causing the EU to starve. The difference in true execution speed
278; (if any) might not be worth the extra 5 bytes.
279; In other words, we could use a real world test here.
280;
281%endif ; 0
282                        ; Bytes EU Cycles(808x/286)
283    xor     dx, dx      ; 2     3/2
284    mov     ax, es      ; 2     2/2
285%rep 4
286    shl     ax, 1       ; 8     8/8
287    rcl     dx, 1       ; 8     8/8
288%endrep
289    add     si, ax      ; 2     3/2
290    adc     dl, dh      ; 2     3/2
291    mov     es, dx      ; 2     2/2
292    ;------------------------------------
293%endif                  ; 26    29/26
294    clc
295    ret
296%endif ; MODULE_8BIT_IDE_ADVANCED
297    ; Fall to IdeTransfer_NormalizePointerInESSI if no MODULE_8BIT_IDE
298
299
300;--------------------------------------------------------------------
301; IdeTransfer_NormalizePointerInESSI
302;   Parameters:
303;       DH:     Number of sectors to transfer (when USE_AT defined)
304;       ES:SI:  Ptr to be normalized
305;   Returns:
306;       ES:SI:  Normalized pointer (SI = 0...15)
307;       AH:     INT 13h Error Code (only when CF set)
308;       CF:     Set of failed to normalize pointer (segment overflow)
309;               Cleared if success
310;   Corrupts registers:
311;       AX, DX
312;--------------------------------------------------------------------
313IdeTransfer_NormalizePointerInESSI:
314; Normalization can cause segment overflow if it is done when not needed
315; (I don't know if any software calls with such seg:off address).
316; This does not apply to XT systems since nothing will write to main BIOS ROM.
317; On AT systems things are quite different, even in protected mode the address
318; is passed in seg:offset form and HMA is accessible in real mode.
319%ifdef USE_AT
320    xor     dl, dl
321    shl     dx, 1
322    dec     dx      ; Prevents normalization when bytes + offset will be zero
323    add     dx, si
324    jc      SHORT .NormalizationRequired
325    ret
326.NormalizationRequired:
327%endif ; USE_AT
328
329    NORMALIZE_FAR_POINTER   es, si, ax, dx
330%ifdef USE_AT       ; CF is always clear for XT builds
331    mov     ah, 0   ; Clear AH and preserve CF
332    rcl     ah, 1   ; RET_HD_INVALID
333%endif
334    ret
335
336
337
338; Lookup tables to get transfer function based on bus type
339ALIGN WORD_ALIGN
340g_rgfnPioRead:
341        dw      IdePioBlock_ReadFrom16bitDataPort   ; 0, DEVICE_16BIT_ATA
342        dw      IdePioBlock_ReadFrom32bitDataPort   ; 1, DEVICE_32BIT_ATA
343%ifdef MODULE_8BIT_IDE
344        dw      IdePioBlock_ReadFrom8bitDataPort    ; 2, DEVICE_8BIT_ATA
345        dw      IdePioBlock_ReadFromXtideRev1       ; 3, DEVICE_8BIT_XTIDE_REV1
346        dw      IdePioBlock_ReadFromXtideRev2       ; 4, DEVICE_8BIT_XTIDE_REV2
347%ifdef MODULE_8BIT_IDE_ADVANCED
348        dw      IdePioBlock_ReadFrom8bitDataPort    ; 5, DEVICE_8BIT_XTCF_PIO8
349        dw      IdeDmaBlock_ReadFromXTCF            ; 6, DEVICE_8BIT_XTCF_DMA
350%endif
351%endif
352
353
354g_rgfnPioWrite:
355        dw      IdePioBlock_WriteTo16bitDataPort    ; 0, DEVICE_16BIT_ATA
356        dw      IdePioBlock_WriteTo32bitDataPort    ; 1, DEVICE_32BIT_ATA
357%ifdef MODULE_8BIT_IDE
358        dw      IdePioBlock_WriteTo8bitDataPort     ; 2, DEVICE_8BIT_ATA
359        dw      IdePioBlock_WriteToXtideRev1        ; 3, DEVICE_8BIT_XTIDE_REV1
360        dw      IdePioBlock_WriteToXtideRev2        ; 4, DEVICE_8BIT_XTIDE_REV2
361%ifdef MODULE_8BIT_IDE_ADVANCED
362        dw      IdePioBlock_WriteTo8bitDataPort     ; 5, DEVICE_8BIT_XTCF_PIO8
363        dw      IdeDmaBlock_WriteToXTCF             ; 6, DEVICE_8BIT_XTCF_DMA
364%endif
365%endif
Note: See TracBrowser for help on using the repository browser.