1 | ; Project name : Assembly Library |
---|
2 | ; Description : Functions for bit handling. |
---|
3 | |
---|
4 | ; |
---|
5 | ; XTIDE Universal BIOS and Associated Tools |
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team. |
---|
7 | ; |
---|
8 | ; This program is free software; you can redistribute it and/or modify |
---|
9 | ; it under the terms of the GNU General Public License as published by |
---|
10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
11 | ; (at your option) any later version. |
---|
12 | ; |
---|
13 | ; This program is distributed in the hope that it will be useful, |
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
16 | ; GNU General Public License for more details. |
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
18 | ; |
---|
19 | |
---|
20 | ; Section containing code |
---|
21 | SECTION .text |
---|
22 | |
---|
23 | ;-------------------------------------------------------------------- |
---|
24 | ; Bit_GetSetCountToCXfromDXAX |
---|
25 | ; Parameters |
---|
26 | ; DX:AX: Source DWORD |
---|
27 | ; Returns: |
---|
28 | ; CX: Number of bits set in DX:AX |
---|
29 | ; Corrupts registers: |
---|
30 | ; Nothing |
---|
31 | ;-------------------------------------------------------------------- |
---|
32 | ALIGN JUMP_ALIGN |
---|
33 | Bit_GetSetCountToCXfromDXAX: |
---|
34 | push bx |
---|
35 | |
---|
36 | call Bit_GetSetCountToCXfromAX |
---|
37 | mov bx, cx |
---|
38 | xchg ax, dx |
---|
39 | call Bit_GetSetCountToCXfromAX |
---|
40 | xchg ax, dx |
---|
41 | add cx, bx |
---|
42 | |
---|
43 | pop bx |
---|
44 | ret |
---|
45 | |
---|
46 | |
---|
47 | ;-------------------------------------------------------------------- |
---|
48 | ; Bit_GetSetCountToCXfromAX |
---|
49 | ; Parameters |
---|
50 | ; AX: Source WORD |
---|
51 | ; Returns: |
---|
52 | ; CX: Number of bits set in AX |
---|
53 | ; Corrupts registers: |
---|
54 | ; Nothing |
---|
55 | ;-------------------------------------------------------------------- |
---|
56 | ALIGN JUMP_ALIGN |
---|
57 | Bit_GetSetCountToCXfromAX: |
---|
58 | push ax |
---|
59 | |
---|
60 | xor cx, cx |
---|
61 | ALIGN JUMP_ALIGN |
---|
62 | .BitScanLoop: |
---|
63 | shr ax, 1 |
---|
64 | jz SHORT .LastBitInCF |
---|
65 | adc cl, ch |
---|
66 | jmp SHORT .BitScanLoop |
---|
67 | ALIGN JUMP_ALIGN |
---|
68 | .LastBitInCF: |
---|
69 | adc cl, ch |
---|
70 | |
---|
71 | pop ax |
---|
72 | ret |
---|
73 | |
---|
74 | |
---|
75 | ;-------------------------------------------------------------------- |
---|
76 | ; Bit_SetToDXAXfromIndexInCL |
---|
77 | ; Parameters: |
---|
78 | ; CL: Index of bit to set (0...31) |
---|
79 | ; DX:AX: Destination DWORD with flag to be set |
---|
80 | ; Returns: |
---|
81 | ; DX:AX: DWORD with wanted bit set |
---|
82 | ; Corrupts registers: |
---|
83 | ; Nothing |
---|
84 | ;-------------------------------------------------------------------- |
---|
85 | ALIGN JUMP_ALIGN |
---|
86 | Bit_SetToDXAXfromIndexInCL: |
---|
87 | cmp cl, 16 |
---|
88 | jb SHORT Bit_SetToAXfromIndexInCL |
---|
89 | |
---|
90 | sub cl, 16 |
---|
91 | xchg ax, dx |
---|
92 | call Bit_SetToAXfromIndexInCL |
---|
93 | xchg dx, ax |
---|
94 | add cl, 16 |
---|
95 | ret |
---|
96 | |
---|
97 | ;-------------------------------------------------------------------- |
---|
98 | ; Bit_SetToAXfromIndexInCL |
---|
99 | ; Parameters: |
---|
100 | ; CL: Index of bit to set (0...15) |
---|
101 | ; AX: Destination WORD with flag to be set |
---|
102 | ; Returns: |
---|
103 | ; AX: WORD with wanted bit set |
---|
104 | ; Corrupts registers: |
---|
105 | ; Nothing |
---|
106 | ;-------------------------------------------------------------------- |
---|
107 | ALIGN JUMP_ALIGN |
---|
108 | Bit_SetToAXfromIndexInCL: |
---|
109 | push dx |
---|
110 | |
---|
111 | mov dx, 1 |
---|
112 | shl dx, cl |
---|
113 | or ax, dx |
---|
114 | |
---|
115 | pop dx |
---|
116 | ret |
---|